Inhalte

# SUMMEWENN

Ermittelt, welche Werte in einem Zellbereich ein bestimmtes Kriterium erfüllen, und gibt dann die Summe der übereinstimmenden Werte zurück. Alternativ kann die Funktion ermitteln, welche Werte in einem Zellbereich ein Kriterium erfüllen, und dann die Summe der Werte in den entsprechenden Zellen in einem zweiten Zellbereich zurückgeben.

SUMMEWENN kann nur ein einziges Kriterium auf einen Bereich anwenden. Verwenden Sie SUMMEWENNS, wenn Sie mehrere Kriterien anwenden müssen.

#### Syntax

SUMMEWENN(Bereich; Bedingung [;Summenbereich])

Bereich: Der Zellbereich, auf den „Bedingung“ angewendet wird.

SUMMEWENN unterstützt den Bezugsverkettungsoperator (~) nur im Parameter „Bereich“ und dies auch nur, wenn der optionale Parameter „Summenbereich“ nicht angegeben ist.

Kriterium 1: Ein Kriterium ist ein Textausdruck, der aus einem einzelnen Zellbezug, einer Formel, Zahl oder einem Text berechnet wird. Es wird bei Vergleichen mit Zellinhalten verwendet.

Ein Verweis auf eine leere Zelle wird als Zahlenwert 0 interpretiert.

Ein passender Ausdruck kann sein:

- Eine Zahl oder ein logischer Wert. Ein übereinstimmender Zelleninhalt entspricht dem Zahlenwert oder dem logischen Wert.

- Ein Wert, der mit einem Vergleichs-Operator beginnt (<, <=, =, >, >= oder <>).

  Bei = gilt: Wenn der Wert leer ist, stimmt er mit leeren Zellen überein.

  Bei <> gilt: Wenn der Wert leer ist, stimmt er mit nicht leeren Zellen überein.

  Bei <> gilt: Wenn der Wert nicht leer ist, stimmt er mit jedem Zellinhalt außer dem Wert überein, einschließlich leerer Zellen.

  Hinweis: "=0" stimmt nicht mit leeren Zellen überein.

  Für = und <> gilt: Wenn der Wert nicht leer ist und nicht als Zahlentyp oder einer seiner Untertypen interpretiert werden kann und die Eigenschaft Suchkriterien = und <> müssen auf ganze Zellen zutreffen aktiviert ist, wird mit dem gesamten Zellinhalt verglichen, wenn nicht aktiviert, wird mit jedem Teil des Felds verglichen, der den Kriterien entspricht. Für = und <> gilt: Wenn der Wert nicht leer ist und nicht als Zahlentyp oder einer seiner Untertypen interpretiert werden kann, trifft die Eigenschaft zu.

- Anderer Textwert. Wenn die Eigenschaft Suchkriterien = und <> müssen auf ganze Zellen zutreffen wahr ist, wird der Vergleich mit dem gesamten Zellinhalt durchgeführt, wenn falsch, wird der Vergleich mit jedem Teil des Felds durchgeführt, der den Kriterien entspricht. Der Ausdruck kann Text, Zahlen, reguläre Ausdrücke oder Platzhalter enthalten (falls in den Berechnungsoptionen aktiviert).

Die Suche unterstützt Platzhalter oder reguläre Ausdrücke. Wenn reguläre Ausdrücke aktiviert sind, können Sie "all.*" eingeben, um beispielsweise das erste Vorkommen von "all", gefolgt von beliebigen Zeichen, zu finden. Wenn Sie nach einem Text suchen möchten, der auch ein regulärer Ausdruck ist, müssen Sie entweder jedem Metazeichen oder Operator eines regulären Ausdrucks ein "\" voranstellen oder den Text in \Q…\E einschließen. Die automatische Auswertung von Platzhaltern oder regulären Ausdrücken können Sie unter LibreOffice – Einstellungen Extras – Optionen… – LibreOffice Calc – Berechnen umschalten.

Wenn Sie Funktionen verwenden, bei denen ein oder mehrere Argumente Suchkriterien-Zeichenfolgen sind, die einen regulären Ausdruck darstellen, besteht der erste Versuch darin, die Zeichenfolgen-Kriterien in Zahlen umzuwandeln. Zum Beispiel wird in bestimmten Gebietsschemen ".0" in "0.0" konvertiert und so weiter. Bei Erfolg handelt es sich bei der Übereinstimmung nicht um eine Übereinstimmung mit regulären Ausdrücken, sondern um eine numerische Übereinstimmung. Wenn Sie jedoch zu einem Gebietsschema wechseln, in dem das Dezimaltrennzeichen nicht der Punkt ist, funktioniert die Konvertierung regulärer Ausdrücke. Um die Auswertung des regulären Ausdrucks anstelle eines numerischen Ausdrucks zu erzwingen, verwenden Sie einen Ausdruck, der nicht als numerisch falsch verstanden werden kann, beispielsweise ".[0]" oder ".\0" oder "(?i).0".

Summenbereich: Optional. Der Zellbereich, aus dem die Werte summiert werden. Wenn „Summenbereich“ nicht angegeben ist, werden die Werte in „Bereich“ summiert.

### Beispiele

Betrachten Sie folgende Tabelle

| A | B | C
1 | Produktname | Sales | Revenue
2 | Buntstift | 20 | 65
3 | Stift | 35 | 85
4 | Schulbuch | 20 | 190
5 | Buch | 17 | 180
6 | Buntstift-Set | nicht | nicht

In allen unten stehenden Beispielen enthält der Bereich für die Berechnung der Summe die Zeile 6, diese wird aber ignoriert, da sie Text enthält.

#### Einfache Verwendung

=SUMMEWENN(C2:C6;">=100")

Summiert nur die Werte aus dem Bereich C2:C6, die >=100 sind. Gibt 370 zurück, da die Zellen C2:C3 das Kriterium nicht erfüllen. Die Werte aus „Bereich“ werden summiert, da „Summenbereich“ nicht angegeben ist.

=SUMMEWENN(B2:B5;">=20";C2:C6)

Summiert die Werte aus dem Bereich B2:B6 nur, wenn die entsprechenden Werte im Bereich A1:A5 >=20 sind. Gibt 340 zurück, da die fünfte und sechste Zeile die Bedingung nicht erfüllen.

#### Verwendung mit regulären Ausdrücken

=SUMMEWENN(A2:A6;"Stift";C2:C5)

Summiert Werte aus dem Bereich C2:C6 nur, wenn der entsprechende Bereich in A2:A6 genau mit den Buchstaben „Stift“ übereinstimmt. Gibt 85 zurück, da die Zeilen A2 und A4:A6 die Bedingung nicht erfüllen.

=SUMMEWENN(A2:A6;"*tift*";C2:C6)

Summiert die Werte aus dem Bereich C2:C6 nur, wenn die entsprechende Zelle im Bereich A2:A6 die Buchstaben „tift“ enthält. Gibt den Wert 150 zurück, da die Zeilen A4:A5 die Bedingung nicht erfüllen.

=SUMMEWENN(Produktname;"*tift*";Einnahmen)

Ein benannter Bereich kann als Bereichs- oder Summenbereichsparameter angegeben werden. Wenn die Spalten in der obigen Tabelle beispielsweise „Produktname“, „Verkäufe“ und „Einnahmen“ heißen, gibt die Funktion 150 zurück. Diese Funktion funktioniert nur wie beschrieben, wenn die Namen der Spalten mithilfe des Dialogs Namen festlegen festgelegt wurden.

#### Zellbezug als Bedingung

Wenn Sie eine Bedingung schnell ändern müssen, können Sie sie in einer separaten Zelle angeben und in der Bedingung der Funktion SUMMEWENNS einen Bezug auf diese Zelle verwenden. Zum Beispiel:

=SUMMEWENN(A2:A6;E2;C2:C6)

Wenn E2=Stift, gibt die Funktion 85 zurück, da der Link zur Zelle durch ihren Inhalt ersetzt wird.

#### Technische Information

Diese Funktion ist Teil des OpenDocument-Standards (Open Document Format for Office Applications) Version 1.2. (ISO/IEC 26300:2-2015)

Verwandte Themen

Wiki-Seite zu SUMMEWENN.

SUMME, SUMMEWENNS

ZÄHLENWENN, ZÄHLENWENNS, MINWENNS, MAXWENNS, MITTELWERTWENNS

Liste der regulären Ausdrücke

Bitte unterstützen Sie uns!